initial commit

buildSrc/build.gradle.kts

@@ -0,0 +1,7 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    mavenCentral()
+}

buildSrc/src/main/kotlin/chat-bot.bot-conventions.gradle.kts

@@ -0,0 +1,17 @@
+import org.gradle.api.tasks.compile.JavaCompile
+
+plugins {
+    java
+    id("chat-bot.java-conventions")
+}
+
+val libs = versionCatalogs.named("libs")
+
+dependencies {
+    implementation(project(":bot-api"))
+    implementation(libs.findLibrary("log4j2-api").get())
+}
+
+tasks.withType<JavaCompile> {
+    options.compilerArgs.add("-parameters")
+}

buildSrc/src/main/kotlin/chat-bot.java-conventions.gradle.kts

@@ -0,0 +1,41 @@
+plugins {
+    java
+}
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(21))
+    }
+}
+
+repositories {
+    mavenLocal()
+    mavenCentral()
+}
+
+val libs = versionCatalogs.named("libs")
+
+dependencies {
+    compileOnly(libs.findLibrary("lombok").get())
+    annotationProcessor(libs.findLibrary("lombok").get())
+
+    testImplementation(platform(libs.findLibrary("junit-bom").get()))
+    testImplementation(libs.findLibrary("junit-jupiter").get())
+
+    testCompileOnly(libs.findLibrary("lombok").get())
+    testAnnotationProcessor(libs.findLibrary("lombok").get())
+}
+
+tasks.withType<JavaCompile> {
+    options.compilerArgs.add("--enable-preview")
+}
+
+tasks.withType<Test> {
+    useJUnitPlatform()
+    jvmArgs("--enable-preview")
+}
+
+val application = extensions.findByType<JavaApplication>()
+application?.apply {
+    applicationDefaultJvmArgs = listOf("--enable-preview")
+}