buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath("org.owasp:dependency-check-gradle:6.5.0.1")
    }
}

subprojects {
    apply(plugin = "java-library")
    apply(plugin = "org.owasp.dependencycheck")

    group = "eu.jonahbauer"
    version = "1.0-SNAPSHOT"

    val implementation by configurations
    val testImplementation by configurations
    val compileOnly by configurations
    val annotationProcessor by configurations
    val runtimeOnly by configurations

    repositories {
        mavenCentral()
    }

    dependencies {
        implementation("org.jetbrains:annotations:23.0.0")

        implementation("org.apache.logging.log4j:log4j-api:2.19.0")
        runtimeOnly("org.apache.logging.log4j:log4j-core:2.19.0")
        runtimeOnly("org.apache.logging.log4j:log4j-slf4j-impl:2.19.0")

        testImplementation("org.junit.jupiter:junit-jupiter:5.8.1")
        testImplementation("org.junit.jupiter:junit-jupiter-engine:5.8.1")
        testImplementation("org.junit.jupiter:junit-jupiter-params:5.8.1")

        compileOnly("org.projectlombok:lombok:1.18.24")
        annotationProcessor("org.projectlombok:lombok:1.18.24")
    }

    tasks {
        withType<JavaCompile> {
            options.encoding = "UTF-8"
        }

        withType<Jar> {
            onlyIf {
                !project.the<SourceSetContainer>()["main"].allSource.isEmpty
            }
        }

        named<Test>("test") {
            useJUnitPlatform()
        }

        named("check") {
            dependsOn("dependencyCheckAnalyze")
        }
    }

    configure<JavaPluginExtension> {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    configure<org.owasp.dependencycheck.gradle.extension.DependencyCheckExtension> {
        format = org.owasp.dependencycheck.reporting.ReportGenerator.Format.JUNIT
    }
}