migration to gradle kotlin dsl

wizard-client/wizard-client-libgdx/build.gradle

@@ -1,30 +0,0 @@
-subprojects {
-    ext {
-        gdxVersion = '1.10.0'
-        roboVMVersion = '2.3.12'
-        box2DLightsVersion = '1.5'
-        ashleyVersion = '1.7.3'
-        aiVersion = '1.8.2'
-        gdxControllersVersion = '2.1.0'
-    }
-}
-
-project(":wizard-client:wizard-client-libgdx:desktop") {
-    apply plugin: "java-library"
-
-    dependencies {
-        implementation project(":wizard-client:wizard-client-libgdx:core")
-        api "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
-        api "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
-        api "com.badlogicgames.gdx:gdx-box2d-platform:$gdxVersion:natives-desktop"
-    }
-}
-
-project(":wizard-client:wizard-client-libgdx:core") {
-    apply plugin: "java-library"
-
-    dependencies {
-        api "com.badlogicgames.gdx:gdx:$gdxVersion"
-        api "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
-    }
-}

wizard-client/wizard-client-libgdx/build.gradle.kts

@@ -0,0 +1,20 @@
+
+project(":wizard-client:wizard-client-libgdx:desktop") {
+    apply(plugin = "java-library")
+
+    dependencies {
+        implementation(project(":wizard-client:wizard-client-libgdx:core"))
+        api("com.badlogicgames.gdx:gdx-backend-lwjgl3:1.10.0")
+        api("com.badlogicgames.gdx:gdx-platform:1.10.0:natives-desktop")
+        api("com.badlogicgames.gdx:gdx-box2d-platform:1.10.0:natives-desktop")
+    }
+}
+
+project(":wizard-client:wizard-client-libgdx:core") {
+    apply(plugin = "java-library")
+
+    dependencies {
+        api( "com.badlogicgames.gdx:gdx:1.10.0")
+        api("com.badlogicgames.gdx:gdx-box2d:1.10.0")
+    }
+}

wizard-client/wizard-client-libgdx/core/build.gradle

@@ -1 +0,0 @@
-[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

wizard-client/wizard-client-libgdx/core/build.gradle.kts

@@ -0,0 +1,6 @@
+val texturePackerSource = "src/main/textures"
+val texturePackerResources = "$buildDir/generated/sources/texturePacker/resources/main"
+val texturePackerGeneratedSources = "$buildDir/generated/sources/texturePacker/java/main"
+
+sourceSets.main.get().java.srcDir(texturePackerGeneratedSources)
+sourceSets.main.get().resources.srcDir(texturePackerResources)

wizard-client/wizard-client-libgdx/desktop/build.gradle

@@ -1,17 +0,0 @@
-plugins {
-    id 'application'
-}
-
-application {
-    mainClass = "eu.jonahbauer.wizard.client.libgdx.desktop.DesktopLauncher"
-
-    run {
-        ignoreExitValue true
-    }
-}
-
-distributions {
-    main {
-        distributionBaseName = 'wizard-client'
-    }
-}

wizard-client/wizard-client-libgdx/desktop/build.gradle.kts

@@ -0,0 +1,17 @@
+plugins {
+    application
+}
+
+application {
+    mainClass.set("eu.jonahbauer.wizard.client.libgdx.desktop.DesktopLauncher")
+
+    tasks.withType<JavaExec> {
+        isIgnoreExitValue = true
+    }
+}
+
+distributions {
+    main {
+        distributionBaseName.set("wizard-client")
+    }
+}